/**************************************************************/
/*  File dsk6713.cmd                                          */
/*    This linker command file can be used as the starting    */
/*  point for linking programs for the TMS320C6713 DSK.       */
/*  CCS v5.1 does not support RTDX.                           */
/*                                                            */
/*  This CMD file assumes everything fits into internal RAM.  */
/*  If that's not true, map some sections to the external     */
/*  SDRAM.                                                    */
/**************************************************************/

-c
-heap  0x1000
-stack 0x1000

-i c:\c6713dsk\dsk6713bsl32\lib
-i "c:\Program Files\C6xCSL\lib_3x"
/* -i C:\ti\bios_5_41_11_38\packages\ti\rtdx\lib\c6000 */

-lrts6700.lib
-ldsk6713bsl32.lib
-lcsl6713.lib

--diag_suppress=16002   /* Supress some harmless warnings */

_HWI_Cache_Control = 0; /* For DSP BIOS */

MEMORY
{
  VECS:  origin = 0x0,         len = 0x00000260   /* interrupt vectors and interrupt
                                                service routine jump table in L2 RAM */
  PMEM:  origin = 0x00000260,  len = 0x0002FDA0   /* Remainder of 192 kB (0x30000 byte)
                                                     internal L2 RAM*/
  BMEM:  origin = 0x80000000,  len = 0x01000000   /* CE0, SDRAM, 16 MBytes */
  FLASH: origin = 0x90000000,  len = 0x40000      /* 256 Kbytes flash mem  */
}


SECTIONS
{
  .intvecs:   load = 0x00000000 /* Interrupt vectors included */
                                /*     by using intr_reset()  */ 
  .text:       load = PMEM      /* Executable code            */ 
  .const:      load = PMEM      /* Initialized constants      */
  .bss:        load = PMEM      /* Global and static variables*/
  .data:       load = PMEM      /* Data from .asm programs    */
  .cinit:      load = PMEM      /* Tables for initializing    */
                                /*    variables and constants */
  .pinit:      load = PMEM
  .stack:      load = PMEM      /* Stack for local variables   */
  .far:        load = PMEM      /* Global and static variables */
                                /* declared far */
  .sysmem:     load = PMEM      /* Used by malloc, etc. (heap) */
  .cio:        load = PMEM      /* Used for C I/O functions    */
  .csldata     load = PMEM
  .switch      load = PMEM
}