Input File for Cantilever I-Beam


/*
 *  =================================================================
 *  Finite element model of I-beam using 4 node shell finite element.
 *
 *  Written By : Lanheng Jin                            May, 27, 1994
 *  =================================================================
 */

print "*** DEFINE PROBLEM SPECIFIC PARAMETERS \n\n";

NDimension         = 3;
NDofPerNode        = 6;
MaxNodesPerElement = 4;

/*
 *  ===============
 *  Define the Mesh
 *  ===============
 */

StartMesh();

print "*** GENERATE GRID OF GEOMETRY FOR FE MODEL \n\n";

L   =   40 in;   /*  Length    */
bb  =   10 in;   /*  Width     */
h   =    5 in;   /*  Height    */
t   = 0.25 in;   /*  Thickness */

print "*** GENERATE GRID OF NODES FOR FE MODEL \n\n";

dL = L/4.0;
nn = 5;

for(j=1; j<=nn; j=j+1) {

     for(i=1; i<=3; i=i+1) {
          nodeno = i + 6*(j-1);
          x = dL*(j-1);
          y = (i-2)*bb*0.5;
          z = 0.5*h;
          AddNode(nodeno,[x,y,z]);  
      }

     for(i=4; i<=6; i=i+1) {
          nodeno = i + 6*(j-1);
          x = dL*(j-1);
          y = (i-5)*bb*0.5;
          z = -0.5*h;
          AddNode(nodeno,[x,y,z]);  
      }

}

print "*** ATTACH ELEMENTS TO GRID OF NODES \n\n";

for(i=1; i < nn; i=i+1) {

     for(j=1; j<=2; j=j+1) {
          elmtno = j + 5*(i-1);
          a = j + 6*(i-1);
          b = j + 6*i;
          c = b + 1;
          d = a + 1;
          node_connec = [a, b, c, d];
          AddElmt(elmtno, node_connec, "name_of_elmt_attr");
      }

     elmtno = 3 + 5*(i-1);
     a = 5 + 6*(i-1);
     b = 5 + 6*i;
     c = 2 + 6*i;
     d = 2 + 6*(i-1);
     node_connec = [a, b, c, d];
     AddElmt(elmtno, node_connec, "name_of_elmt_attr");

     for(j=4; j<=5; j=j+1) {
          elmtno = j + 5*(i-1);
          a = j + 6*(i-1);
          b = j + 6*i;
          c = b + 1;
          d = a + 1;
          node_connec = [a, b, c, d];
          AddElmt(elmtno, node_connec, "name_of_elmt_attr");
      }

}

/*
 *  ===============================================
 *  Define Element, Section and Material Properties
 *  ===============================================
 */

print "*** DEFINE ELEMENT, SECTION AND MATERIAL PROPERTIES \n\n";

ElementAttr("name_of_elmt_attr") { type     = "SHELL_4NQ";
                                   section  = "mysection";
                                   material = "ELASTIC";
                                  }

MaterialAttr("ELASTIC") { poisson = 0.3;   
		          E       = 1E+7 psi;
                         }

SectionAttr("mysection") { thickness =   0.25 in; }

/*
 *  =========================
 *  Setup Boundary Conditions
 *  =========================
 */

print "*** SET UP BOUNDARY CONDITIONS \n\n";

/*  full fixity condition  */

u_id  = 1; v_id  = 1; w_id  = 1;
rx_id = 1; ry_id = 1; rz_id = 1;
bc_fc = [u_id,v_id,w_id,rx_id,ry_id,rz_id];

/*  apply full fixity to corner nodes  */

for (i=1; i<=6; i=i+1) {
     FixNode(i, bc_fc);
}

/*
 *  ==================
 *  Add external loads
 *  ==================
 */

print "*** APPLY EXTERNAL LOADS \n\n";

/* [0] load for end nodes  */

Fx = 0 lbf;    Fy = (-1.0 psi)*L*L;    Fz = 0 lbf;
Mx = 0 lbf*in; My = 0 lbf*in; Mz = 0 lbf*in;
i1 = 6*nn-3;
NodeLoad(i1,[Fx, Fy, Fz, Mx, My, Mz]);

Fx = 0 lbf;    Fy = (1.0 psi)*L*L;    Fz = 0 lbf;
Mx = 0 lbf*in; My = 0 lbf*in; Mz = 0 lbf*in;
i1 = 6*nn-2;
NodeLoad(i1,[Fx, Fy, Fz, Mx, My, Mz]);

/*
 *  =====================================
 *  Compile and Print Finite Element Mesh
 *  =====================================
 */

EndMesh();
PrintMesh();

/*
 *  ==========================
 *  Compute Stiffness Matrices
 *  ==========================
 */

print "\n*** COMPUTE STIFFNESS MATRICES \n\n";

SetUnitsType("US");
stiff = Stiff();
eload = ExternalLoad();
lu    = Decompose(Copy(stiff));
displ = Substitution(lu, eload);

/*
 *  ================================
 *  Print displacements and stresses
 *  ================================
 */

PrintDispl(displ);
PrintStress(displ);

quit;


Points to note are:

  1. This input file is for Cantilever I-beam with mesh 4, Under Two Level Concentrated Loads at the Flanges of the Free End in Opposite Directions Along y.
  2. In part 1 we specify that this will be a three-dimensional analysis. The maximum number of degrees of freedom per node will be six, and the maximum number of nodes per element will be four. The parameters NDimension, NDofPerNode, and MaxNodesPerElement are used by ALADDIN to assess memory requirements for the problem storage and solution.
  3. We used for() loop to generate the mesh of 30 finite element nodes and 20 elements. Before the boundary conditions are applied, the structure has 180 degrees of freedom. In Boundary Section, we apply full-fixity to fixed end of the cantilever -- this reduces degrees of freedom from 180 to 144.


Developed in June 1996 by Mark Austin
Last Modified June 27, 1996
Copyright © 1996, Mark Austin, Department of Civil Engineering, University of Maryland